
Exercises: <https://elearning.unipv.it/pluginfile.php/205963/mod_resource/content/3/2_sparql_exercises.pdf>

Solutions: <https://elearning.unipv.it/pluginfile.php/206599/mod_resource/content/1/2_sparql_solutions.pdf>

# Exercise 1



1. ex:bob foaf:knows ex: alice, ex:alice foaf:knows ex:carol
2. ex:bob a ex:Person, ex:carol a ex:Person
3. ex:bob rdf:type ex:Person
4. ex:alice foaf:knows ex:carol. ex:carol a ex:Student
5. ex:alice foaf:knows ex:carol. ex:carol a ex:Student. ex:carol foaf:name “Carol”

# Exercise 2

## Retrieve 100 triples

SELECT ?s ?p ?o

WHERE {?s ?p ?o}

LIMIT 100

## Retrieve 100 distinct triples

SELECT DISTINCT ?s ?p ?o

WHERE {?s ?p ?o}

LIMIT 100

## Retrieve 100 distinct predicates

SELECT DISTINCT ?p

WHERE {?s ?p ?o}

LIMIT 100

## Retrieve 100 people

SELECT DISTINCT ?s

WHERE {?s a dbo:Person}

LIMIT 100

## Retrieve predicates that have a resource of type person as subject

SELECT DISTINCT ?p

WHERE {?s ?p ?o.

?s rdf:type dbo:Person}

LIMIT 100

## Retrieve the birth names and years of 100 people

SELECT DISTINCT ?name ?year

WHERE {

?s rdf:type dbo:Person.

?s dbo:birthName ?name.

?s dbo:birthYear ?year

}

LIMIT 100

## Retrieve the birth names of 100 people born in 1984, order by name

SELECT \*

WHERE {?x rdf:type dbo:Person;

dbo:birthYear "1984"^^ <http://www.w3.org/2001/XMLSchema#gYear> ;

dbo:birthName ?name}

ORDER BY ?name

LIMIT 100

## Retrieve the length of the Nile river

SELECT ?len

WHERE {dbr:Nile dbo:length ?len}

## Retrieve trumpet players that were also bandleaders.

SELECT DISTINCT ?uri

WHERE { ?uri dbo:occupation dbr:Bandleader . ?uri dbo:instrument dbr:Trumpet . }

## Retrieve movies that were written, directed and produced by the same person

SELECT DISTINCT ?movie

WHERE { ?movie rdf:type dbo:Film.

?movie dbo:director ?x.

?movie dbo:producer ?x.

?movie dbo:writer ?x

}

LIMIT 100

# Exercise 3

## Retrieve names of writers and, if available, their birth year

SELECT DISTINCT ?name ?year

WHERE {?writer rdf:type dbo:Writer.

?writer dbo:birthName ?name.

OPTIONAL {?writer dbo:birthYear ?year

}}

LIMIT 100

## The same as the previous query but, if available, retrieve their birth place

SELECT DISTINCT ?name ?year ?place

WHERE {?writer rdf:type dbo:Writer.

?writer dbo:birthName ?name.

OPTIONAL {?writer dbo:birthYear ?year}

OPTIONAL {?writer dbo:birthPlace ?place}

}

LIMIT 100

## Retrieve movies that were written, directed and produced by the same person. If available, retrieve their box-office gross

SELECT ?movie ?x ?y

WHERE { ?movie rdf:type dbo:Film.

?movie dbo:director ?x.

?movie dbo:writer ?x.

?movie dbo:producer ?x.

OPTIONAL{ ?movie dbp:budget ?y

}

}

LIMIT 200

ORDER BY ?movie

## Retrieve movies that were written, directed or produced by Charlie Kaufman

SELECT ?movie

WHERE {

{ ?movie dbo:writer dbr:Charlie\_Kaufman}

UNION { ?movie dbo:director dbr:Charlie\_Kaufman}

UNION {?movie dbo:producer dbr:Charlie\_Kaufman}

}

## Retrieve people that were born in Milan or in Rome

SELECT ?person

WHERE {

{ ?person dbo:birthPlace dbr:Rome}

UNION { ?person dbo:birthPlace dbr:Milan}

}

LIMIT 200

## Same as the previous query, but also retrieve the occupation for people born in Milan

SELECT ?person ?z

WHERE {

{ ?person dbo:birthPlace dbr:Rome}

UNION { ?person dbo:birthPlace dbr:Milan;

dbo:occupation ?z }

}

LIMIT 2000

## Same as the previous query, but retrieve the occupation for people born in Milan only if available

SELECT ?person ?z

WHERE {

{ ?person dbo:birthPlace dbr:Rome}

UNION { ?person dbo:birthPlace dbr:Milan.

OPTIONAL {?person dbo:occupation ?z }

}

}

LIMIT 2000

# Exercise 4

## Retrieve movies that were written, directed or produced by Charlie Kaufman

SELECT ?movie

WHERE {

{ ?movie dbo:writer dbr:Charlie\_Kaufman}

UNION { ?movie dbo:director dbr:Charlie\_Kaufman}

UNION {?movie dbo:producer dbr:Charlie\_Kaufman}

}

## Retrieve people that were born or that live in Milan.

SELECT ?person

WHERE {?person rdf:type dbo:Person.

{?person dbo:birthPlace dbr:Milan}

UNION

{?person dbo:residence dbr:Milan}

}

## 

## Retrieve people that have written or directed a movie.

SELECT DISTINCT ?w

WHERE { ?m dbo:writer|dbo:director ?w }

## Retrieve the names of notable works of Elena Ferrante

SELECT DISTINCT ?works

WHERE { dbr:Elena\_Ferrante dbo:notableWork/

dbp:name ?works }

## Retrieve the grandparents of Elizabeth II

SELECT DISTINCT ?grand

WHERE { dbr:Elizabeth\_II dbo:parent/dbo:parent ?grand

}

## Retrieve all ancestors of Elizabeth II

SELECT DISTINCT ?anc

WHERE { dbr:Elizabeth\_II dbo:parent+ ?anc

}

## Retrieve the parents, the grandparents, the great-grandparents, and the great-great-grandparents of Elizabeth II

SELECT DISTINCT ?anc

WHERE { dbr:Elizabeth\_II dbo:parent/dbo:parent?/dbo:parent?/dbo:parent? ?anc

}

# Exercise 5

## Was Natalie Portman born in (some city of) the US?

ASK

WHERE { dbr:Natalie\_Portman dbo:birthPlace/ dbo:country dbr:United\_States

}

## 

## Is Rome the capital of Italy?

ASK

WHERE {dbr:Italy dbo:capital dbr:Rome}

## Describe Rome

describe dbr:Rome

## Describe 20 people born in Italy

DESCRIBE ?person

WHERE {?person rdf:type dbo:Person.

?person dbo:birthPlace/dbo:country dbr:Italy}

LIMIT 20

## Construct the graph of the ancestors of dbo:Elizabeth\_II

CONSTRUCT { ?x dbo:parent ?y }

WHERE { ?x dbo:parent ?y . dbr:Elizabeth\_II dbo:parent\* ?x }